source: mediastreamer2/src/CMakeLists.txt @ 1074:18bd4cfab392

set(PACKAGE "mediastreamer2")
set(PACKAGE_BUGREPORT "mediastreamer2")
set(PACKAGE_NAME "mediastreamer2")
set(PACKAGE_STRING "${PACKAGE} ${ORTP_VERSION}")
set(PACKAGE_PLUGINS_DIR "plugins/")

if(ANDROID)
  set(CMAKE_THREAD_LIBS_INIT "-lc")
  set(MS_LIBS ${MS_LIBS} m)
endif()
include(FindThreads)

set(MS_SRCS mscommon.c msfilter.c msqueue.c msticker.c alaw.c ulaw.c mssndcard.c msrtp.c
        dtmfgen.c ice.c tee.c msconf.c msjoin.c msvolume.c mswebcam.c mtu.c void.c eventqueue.c
        dsptools.c kiss_fft.c  kiss_fftr.c equalizer.c audiostream.c )

if(LINUX AND NOT ANDROID)
  set(MS_SRCS ${MS_SRCS} oss.c)
  find_library(ALSA  asound)
  if (ALSA)
    set(MS_SRCS  ${MS_SRCS} alsa.c)
    set(MS_LIBS  ${MS_LIBS} ${ALSA})
    add_definitions(-D__ALSA_ENABLED__)
  endif(ALSA)
  add_definitions(-DHAVE_DLOPEN)
endif(LINUX AND NOT ANDROID)

if(WIN32)
  include_directories(../build/win32native/)
  set(MS_SRCS ${MS_SRCS} winsnd3.c ../build/win32native/mediastreamer2.def msfileplayer_win.c msfilerec_win.c)
  
else(WIN32)
  set(MS_SRCS ${MS_SRCS} msfileplayer.c msfilerec.c)
endif(WIN32)

find_file(GSM_GSM_H gsm/gsm.h PATHS ${GSM_INCLUDE_DIRS})
if(GSM_GSM_H)
  find_library(GSM_LIB gsm)
endif(GSM_GSM_H)

if(GSM_LIB)
  include_directories(${GSM_INCLUDE_DIRS})
  set(MS_LIBS ${MS_LIBS} ${GSM_LIB})
  set(MS_SRCS ${MS_SRCS} gsm.c)
else(GSM_LIB)
  include_directories(${GSM_INCLUDE_DIRS})
  set(MS_LIBS ${MS_LIBS} ${GSM_LIBRARIES})
  set(MS_SRCS ${MS_SRCS} gsm.c)
endif(GSM_LIB)

find_file(SPEEX_H speex/speex.h PATHS ${SPEEX_INCLUDE_DIRS})
if(SPEEX_H)
  set(MS_LIBS  ${MS_LIBS} ${SPEEX_LIBRARIES} ${SPEEXDSP_LIBRARIES})
  set(MS_SRCS ${MS_SRCS} msspeex.c msresample.c)
  include_directories(${SPEEX_INCLUDE_DIRS})
else(SPEEX_H)
  add_definitions(-DDISABLE_SPEEX)
endif(SPEEX_H)

if(PORTAUDIO_FOUND)
  add_definitions(
    -D__PORTAUDIO_ENABLED__
  )
  set(MS_SRCS  ${MS_SRCS} pasnd.c)
  set(MS_LIBS  ${MS_LIBS} ${PORTAUDIO_LIBRARIES})
endif(PORTAUDIO_FOUND)

if(NOT CMAKE_UNDER_CE)
        TEST_BIG_ENDIAN(BIG_ENDIAN)
        if(BIG_ENDIAN)
          add_definitions(
                -DORTP_BIGENDIAN
                -DWORDS_BIGENDIAN
          )
        endif(BIG_ENDIAN)
endif(NOT CMAKE_UNDER_CE)

if(NOT WIN32)
        # We want to generated the alldescs.h file
        # Step 1:
        #   Find all calls to MS_FILTER_DESC_EXPORT macro in the source file and extract the arguments
        foreach(f ${MS_SRCS})
         file(READ ${f} fc)
         string(REGEX MATCHALL "MS_FILTER_DESC_EXPORT\(.*\)" mcs ${fc})
        # message("matches for ${f} are ${mcs}")
         set(fds ${fds} ${mcs})
        endforeach(f)

        string(REPLACE "MS_FILTER_DESC_EXPORT\(" "" fds ${fds})
        string(REPLACE "\)" " " fds ${fds})
        string(REPLACE "\n" "" fds ${fds})
        string(REPLACE " " ";" fds ${fds})
        set(fds ${fds})

        # Here the 'fds' variable contains the list of filter names
        #message("fds = ${fds}")

        # Step 2:  Generate the file which refernces all the descriptors
        set(fn "${CMAKE_CURRENT_BINARY_DIR}/alldescs.h")
        file(WRITE ${fn} "#include \"mediastreamer2/msfilter.h\"\n\n")
        foreach(fd ${fds})
          file(APPEND ${fn} "extern MSFilterDesc ${fd};\n")
        endforeach(fd)
        file(APPEND ${fn} "MSFilterDesc *ms_filter_descs[]={\n")
        foreach(fd ${fds})
          file(APPEND ${fn} "&${fd},\n")
        endforeach(fd)
        file(APPEND ${fn} "0\n};\n")
endif(NOT WIN32)

configure_file("${CMAKE_CURRENT_SOURCE_DIR}/mediastreamer-config.h.cmake" "${CMAKE_CURRENT_BINARY_DIR}/mediastreamer-config.h")
add_definitions(
        -DHAVE_CONFIG_H
        )

include_directories(${mediastreamer_SOURCE_DIR}/include ${CMAKE_CURRENT_BINARY_DIR} ${ORTP_INCLUDE_DIRS})
set(MEDIASTREAMER_INCLUDE_DIRS ${mediastreamer_SOURCE_DIR}/include CACHE STRING "mediastreamer2 include dir")

add_library(mediastreamer SHARED ${MS_SRCS})
set_target_properties(mediastreamer PROPERTIES VERSION ${MEDIASTREAMER_VERSION_STRING} SOVERSION 
  ${MEDIASTREAMER_VERSION_STRING})
target_link_libraries(mediastreamer ${MS_LIBS} ${ORTP_LIBRARIES})
set(MEDIASTREAMER_LIBRARIES mediastreamer CACHE STRING "mediastreamer2 libraries")